Loop Files

Loop Files FilePattern , Mode

Loop Files, "C:\My Documents\Address List.txt"
    ShortPathName := A_LoopFileShortPath

if A_LoopFileAttrib ~= "[HRS]"  ; 跳过任何具有 H(隐藏), R(只读) 或 S(系统). 请参阅 ~= 运算符.
    continue  ; 跳过这个文件并继续下一个文件.

FileList := ""
Loop Files, "*.jpg"
    FileList .= A_LoopFileName "`n"
Loop Parse, FileList, "`n"
    FileMove A_LoopField, "renamed_" A_LoopField

报告位于目录及其子目录中的每个文本文件的完整路径.

Loop Files, A_ProgramFiles "\*.txt", "R"  ; 递归子文件夹.
{
    Result := MsgBox("Filename = " A_LoopFilePath "`n`nContinue?",, "y/n")
    if Result = "No"
        break
}

计算文件夹的大小, 包括其所有子文件夹中的文件.

FolderSizeKB := 0
WhichFolder := DirSelect()  ; 让用户选取文件夹.
Loop Files, WhichFolder "\*.*", "R"
    FolderSizeKB += A_LoopFileSizeKB
MsgBox "Size of " WhichFolder " is " FolderSizeKB " KB."

获取根据名称排序的文件名(要以日期排序请参阅下一个例子).

FileList := ""  ; 初始化为空.
Loop Files, "C:\*.*"
    FileList .= A_LoopFileName "`n"
FileList := Sort(FileList, "R")  ; R 选项逆序排列. 有关其他选项, 请参阅 Sort.
Loop Parse, FileList, "`n"
{
    if A_LoopField = ""  ; 忽略列表末尾的空项.
        continue
    Result := MsgBox("File number " A_Index " is " A_LoopField ".  Continue?",, "y/n")
    if Result = "No"
        break
}

获取根据修改日期排序的文件名.

FileList := ""
Loop Files, A_MyDocuments "\Photos\*.*", "FD"  ; 包含文件和子目录
    FileList .= A_LoopFileTimeModified "`t" A_LoopFileName "`n"
FileList := Sort(FileList)  ; 根据日期排序.
Loop Parse, FileList, "`n"
{
    if A_LoopField = "" ; 忽略列表末尾的最后一个换行符(空项).
        continue
    FileItem := StrSplit(A_LoopField, A_Tab)  ; 用 tab 作为分隔符将其分为两部分.
    Result := MsgBox("The next file (modified at " FileItem[1] ") is:`n" FileItem[2] "`n`nContinue?",, "y/n")
    if Result = "No"
        break
}

仅复制比目标位置中的对应文件更新的源文件.

CopyIfNewer:
; 调用者已经为我们赋值了变量 CopySourcePattern 和 CopyDest.
Loop Files, CopySourcePattern
{
    copy_it := false
    if !FileExist(CopyDest "\" A_LoopFileName)  ; 如果目标文件还不存在, 那么总是复制.
        copy_it := true
    else
    {
        time := FileGetTime(CopyDest "\" A_LoopFileName)
        time := DateDiff(A_Now, A_LoopFileTimeModified, "Seconds")  ; 从目的时间中减去源文件的时间.
        if time < 0  ; 源文件比目的文件新.
            copy_it := true
    }
    if copy_it
    {
        try
            FileCopy A_LoopFilePath, CopyDest "\" A_LoopFileName, 1   ; 以覆盖形式复制 overwrite=yes
        catch
            MsgBox 'Could not copy "' A_LoopFilePath '" to "' CopyDest '\' A_LoopFileName '".'
    }
}
Return

把通过命令行参数传递的文件名转换为长名称, 完整路径和在文件系统中存储的正确的大写/小写字符形式.

for GivenPath in A_Args  ; 对于每一个参数(或拖放到脚本中的文件):
{
    Loop Files, GivenPath, "FD"  ; 包括文件和目录.
        LongPath := A_LoopFilePath
    MsgBox "The case-corrected long path name of file`n" GivenPath "`nis:`n" LongPath
}